***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 30, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4FL18A-AU A K 
.param
+vc0 = 2.206e-11	vc1 = 2.006e-11		vc2 = 1.000		vc3 = 9.905e-13		vc4 = 2.835e-1
+tc1 = 1.421e-2		tc2 = 1.801e-2		tc3 = 1.501e-2		tc4 = 3.071e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 3.014e-15	   n = 9.744e-1		  rs = 6.810e-3
+ibv = 1.0e-3		 nbv = 1.0		  bv = 21.05
+ikf = 1.335e-0
***** capacitance parameter *****
+cjo = 7.370e-10	   m = 3.362e-1		  vj = 6.159e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.082		 xti = 3
+trs1 = 1e-3		trs2 = -1e-6		tikf = 5.0e-3
+tbv1 = 6.947e-4	tbv2 = 2.802e-7	
.ends P4FL18A-AU
*$
